JOYCE Computerclub    

PRTHELP.BAS als Quelltext ansehen

10 '********* PRTHELP - druckt ein CP/M Plus-Handbuch nach den Daten in HELP.HLP
20 '********* Richard Suchenwirth, Berlin 1986
30 seite=1: zeile=6: zeile.max=65
40 ff$=CHR$(12):fett$=CHR$(27)+"E":mager$=CHR$(27)+"F":breit$=CHR$(14):schmal$=CHR$(20)
50 PRINT"Dieses Programm druckt ein kleines Handbuch für die JOYCE anhand der Datei"
60 PRINT"HELP.HLP (Systemdisketten, Seite 4). Wenn Sie dies nicht wollen, drücken Sie"
70 PRINT"einfach die Taste Q. Anderenfalls:"
80 PRINT"bitte die Systemdiskette, Seite 4, einlegen, Papier"
90 PRINT"auf Seitenanfang stellen, dann eine Taste (außer Q) drücken!"
100 c$=INKEY$:IF c$="" THEN 100
110 IF UPPER$(c$)="Q" THEN END
119 '
120 '************** Initialisierung
121 '
130 IF FIND$("Help.Hlp")="" THEN PRINT CHR$(7): GOTO 80
140 OPEN "I",1,"Help.Hlp"
150 PRINT: PRINT "Druck beginnt"
160 WIDTH LPRINT 80
170 LPRINT CHR$(27)+"R"+CHR$(0);:' Zeichensatz USA
180 LPRINT CHR$(27)+"M";:' Elite
190 LPRINT CHR$(27)+"1"+CHR$(12);:' linker Rand
200 '
210 ' ************ Titelblatt 
211 '
220 FOR i=1 TO 20: LPRINT: NEXT i
230 LPRINT breit$;"HELP.HLP": LPRINT breit$;"for Schneider PCW 8256 JOYCE"
240 FOR i=1 TO 10: LPRINT: NEXT i
250 LPRINT "An offline version of what the HELP command would tell you" 
255 LPRINT:LPRINT"Text by Digital Research Inc.":LPRINT
260 LPRINT "Printout design by Richard Suchenwirth, Berlin 1986"
269 '
270 ' ************** Inhaltsverzeichnis 
271 '
275 titel.wort$="    Contents"
280 GOSUB 410: LPRINT fett$;"Table of Contents";mager$:LPRINT
290 item$=INPUT$(16,1):wort$=LEFT$(item$,12):stufe=ASC(RIGHT$(item$,1))
300 IF stufe >1 THEN wort$=LOWER$(wort$) ELSE LPRINT:zeile=zeile+1:IF zeile>zeile.max THEN GOSUB 410
310 IF LEFT$(wort$,1)<>"$" THEN LPRINT wort$;:GOTO 290
320 LINE INPUT #1,zeile$
329 '
330 ' ************** Schleife: Text drucken 
331 '
340 WHILE NOT EOF(1)
350 LINE INPUT #1,zeile$: neues.thema=INSTR(zeile$,"///")
360 IF neues.thema THEN stufe$=MID$(zeile$,neues.thema+3,1):wort$=UPPER$(MID$(zeile$+SPACE$(12),5,12))
370 IF stufe$="1" THEN titel.wort$=wort$:GOSUB 410:wort$=breit$+wort$+schmal$:stufe$=""
380 IF neues.thema THEN LPRINT:LPRINT fett$;wort$;mager$:zeile=zeile+2 ELSE LPRINT zeile$:zeile=zeile +1
390 IF zeile>zeile.max THEN GOSUB 410
400 WEND:LPRINT SPC(30),"*** End of HELP.HLP ***",ff$: CLOSE 1:END
409 '
410 ' ************* Sub Seitenüberschrift 
411 '
420 seite =seite+1: zeile=3
430 LPRINT ff$;CHR$(27);"-1HELP for the PCW 8256 JOYCE ";SPC(20);titel.wort$;seite;CHR$(27)+"-0":LPRINT:RETURN

 


JOYCE Computerclub - Userclub für Joyce-Anwender Seite 5